help for metamiss2 command

Title

Accounting for missing outcome data in meta-analysis

Description

Missing outcome data are common in randomized controlled trials.
If they are ignored then the estimated treatment effects might be biased.
Meta-analysts usually assume that the missing data problem has been solved at the trial level and proceed to an available case analysis.
This is equivalent to a missing at random assumption (MAR).
However, if reasons for missingness are related to the actual outcome of the trials,
then data are missing not at random (MNAR) and ignoring missing data may lead to a biased summary estimate.

Models that quantify the degree of departure from the MAR assumption are available for both binary and continuous outcome data.
These models relate the mean outcome in the missing data to the mean of the observed data for each group through informative missingness parameters (IMPs).
Either the IMPs are informed by expert opinion, or a sensitivity analysis is conducted to evaluate how sensitive results are to different values of the IMPs.
Different assumptions for the missing pattern are possible by defining
the mean and the variance of the IMP for each study group, and their covariance across study groups.

For continuous data, the metamiss2 command allows two
definitions of the IMP: the informative missingness difference of means (IMDOM)
or the informative missingness ratio of means (IMROM)
(Mavridis et al, 2015).
For binary data, the IMP is the informative missingness odds ratio
(White et al, 2008a).

The models are fitted using a two-step estimation procedure (Chaimani et al, 2018).
At the first step the command estimates the study-specific relative effects using both the observed and missing participants.
At the second step it calls metan (for standard
pairwise meta-analysis) or network meta (for network meta-analysis)
to obtain the summary effects from the 'adjusted' study-specific relative effects.

Using metamiss2 typically has two impacts.
Firstly, the point estimates are changed; this primarily reflects non-zero means of the IMPs.
Secondly, the variances are increased, so that less relative weight is assigned to trials with high or unbalanced missing rates: this primarily reflects non-zero standard deviations of the IMPs.

Syntax

metamiss2
[varlist]
[if exp]
[in range]
[,
imptype(imdom|logimrom)
impmean(exp exp...exp)
impsd(exp exp...exp)
impcorrelation(real|matrix)
fixed
tau2(string)
inconsistency
md
smd
rom
or
rr
rd
sdpool(on|off)
taylor
bootstrap
reps(integer)
seed(integer)
compare(string)
sensitivity
nokeep
nometa
varchange
netplot
trtlabels(string)
netplotreference(string)
netplotoptions(intervalplot_options)
metanoptions(meta_options)
networkoptions(network_meta_options)]

where varlist is:

- for pairwise meta-analysis with continuous outcome data: nE mE yE sdE nC mC yC sdC -
variables containing the numbers of observed and missing participants,
the mean and standard deviation of the observed data in experimental and control group respectively.

- for pairwise meta-analysis with binary outcome data:
rE fE mE rC fC mC - variables containing the numbers of successes and failures in the observed data and the number
of missing participants in experimental and control group respectively.

- for network meta-analysis:
varlist is not used but the data must have been prepared using the network setup command in the augmented format (see the exmple).

Options for specifying the IMPs

imptype(imdom|logimrom) specifies the type of IMP for continuous outcome data. The default is imdom. This option is not needed for
binary outcome data since the only available IMP is logimor. For details on the definition of IMDOM, logIMROM and logIMOR see the Description
above, (Mavridis et al, 2015) and (White et al, 2008a).

impmean(exp exp...exp) specifies the mean of the assumed (normal) distribution for IMP. The default value is 0 in all groups.
If one value is given, it is the mean for all groups. For pairwise meta-analysis, if two values are given, they are the means for the experimental and control group.
For network meta-analysis, if T values are given (with T the total number of treatments), they are the means for the reference treatment and the non-reference
treatments in the order shown in network setup. Each exp may be a single value corresponding to all studies or a variable containing study-specific values.

impsd(exp exp...exp) specifies the correlation of the IMP between the different groups. The default value is 0.
A common correlation value for all pairs of treatments or the full TxT correlation matrix (only for network meta-analysis) can be specified.

impcorrelation(real|matrix) specifies the correlation of the IMP between the different groups. The default value is 0.
A common correlation value for all pairs of treatments or the full correlation matrix (only for network meta-analysis) can be specified.

compare(string) specifies a second assumption for IMP to be compared to the primary analysis. String may include impmean(), impsd()
and impcorrelation().

sensitivity specifies a sensitivity analysis for the IMP assuming a range of different standard deviations for its distribution with impmean(0)
or a different specified impmean().

Options for continuous data

smd specifies standardized mean difference as the measure of interest (the default for continuous data).

md specifies mean difference as the measure of interest.

rom specifies ratio of means as the measure of interest.

sdpool(on|off) specifies whether the standard deviation is pooled across groups in computing variances.
Following metan, the default option for mean difference and ratio of means is sdpool(off) and for standardize mean difference is sdpool(on).

Options for binary data

rr specifies risk ratio as the measure of interest (the default for binary data).
Note that in this case the IMP is the logIMOR.

or specifies odds ratio as the measure of interest.
Note that in this case the IMP is the logIMOR.

rd specifies risk difference as the measure of interest.
Note that in this case the IMP is the logIMOR.

Estimation options

taylor specifies that Taylor-series approximation is used to integrate over the distribution of IMP (the default).

bootstrap specifies that Monte Carlo (bootstrap) is used to integrate over the distribution of IMP.

reps(integer) specifies the number of simulations under the bootstrap method. The default is 10000

seed(integer) specifies the initial value of the random-number seed for bootstrap method. The default is 0.
See set seed for more details.

Meta-analysis options

fixed specifies the use of the fixed-effect model instead of the default random-effects model.

tau2(string) specifies the use of an estimator other than the DerSimonial-Laird estimator for heterogeneity.
This option is available only for pairwise meta-analysis and valid estimators are the available estimators in metaan.

inconsistency specifies the use of an inconsistency model for the case of network meta-analysis instead of the consistency model which is the default.

nometa skips the conduct of standard pairwise or network meta-analysis after estimating the 'adjusted' study-specific effect sizes and variances.

metanoptions(meta_options) are any valid options for metan.

networkoptions(network_meta_options) are any valid options for network meta.

Output options

nokeep specifies that study-specific 'adjusted' effect sizes and standard errors/variances will be dropped from the dataset.
By default, these estimates are stored as extra variables; for pairwise meta-analysis with names _ES, _seES (as in metan) and in network meta-analysis with prefix _imp_.

varchange specifies that the 'adjusted' study-specific relative effects and variances are stored in the dataset replacing the respective values obtained
from the network setup command. This means that the current assumptions about the missing data will also apply to future analyses of the data.

netplot specifies that a forest plot with the relative effects from network meta-analysis will be drawn. The same forest plot can be produced by running the intervalplot
command after metamiss2 for a network meta-analysis. Note that for the case of standard pairwise meta-analysis a forest plot is produced by default.

trtlabels(string) specifies the labels of the treatments for the case of network meta-analysis separated with spaces. These labels will be used in netplot.
The first label should correspond to the reference treatment and the other treatment should be given in the numerical/alphabetical order of their codes in the data.
See also intervalplot.

netplotreference(string) specifies a reference treatment to be used as reference in netplot so as only a subset of the relative effects from the network
meta-analysis (i.e. every treatment vs. that reference) will be given in the forest plot. The treatment specified here can be different from the reference treatment of the analysis.
See also intervalplot.

netplotoptions(intervalplot_options) specifies any additional valid option allowed in intervalplot.

Examples

1. Pairwise meta-analysis, binary data

- Load the data comparing the effectiveness of haloperidol against placebo for the treatment of schizophrenia (Joy, 2006):

. use "http://clinicalepidemio.fr/Stata/haloperidol.dta", clear

(click to run)

- Assume that the logIMOR in the haloperidol group has mean 0 and SD 1, while the logIMOR in the placebo group has mean -1 and SD 1.
This expresses the belief that for placebo the response in missing participants is probably worse than in observed participants:

. metamiss2 rh fh mh rp fp mp, impmean(0 -1) impsd(1) metanopt(lcols(author))

(click to run)

- Next assume that the logIMORs are positively correlated between the two intervention groups, with correlation rho=0.5:

. metamiss2 rh fh mh rp fp mp, impmean(0 -1) impsd(1) impc(0.5) b metanopt(lcols(author))

(click to run)

2. Pairwise meta-analysis, continuous data

- Load the data comparing the effectiveness of mirtazapine versus placebo for major depression (Cipriani, 2009):

. use "http://clinicalepidemio.fr/Stata/mirtazapine.dta", clear

(click to run)

- Assume a systematic departure from the MAR assumption where for the mirtazapine group IMDOM=-0.5 with sd(IMDOM)=1 and for placebo
IMDOM=1 with sd(IMDOM)=1.5. This means that probably placebo performed worse in the missing participants than in the observed,
whereas mirtazapine performed worse in the observed participants. Assume also that IMDOMs are correlated between the two groups with rho=0.5 and compare the results with ACA:

. metamiss2 nm mm ym sdm np mp yp sdp, impmean(-0.5 1) impsd(1 1.5) impcorr(0.5) compare(impmean(0) impsd(0)) md metanopt(lcols(study))

(click to run)

- Change the IMP parameter and run a sensitivity analysis with IMROM=1 on a range of different values for sd(logIMROM):

. metamiss2 nm mm ym sdm np mp yp sdp, md sensitivity b imptype(logimrom)

(click to run)

3. Network meta-analysis

- Load the data that comprise a network of trials comparing the effectiveness of 9 antidepressants (Cipriani, 2009):

. use "http://clinicalepidemio.fr/Stata/antidepressants.dta", clear

(click to run)

- Prepare the data in the "augmented" format:

. network setup y sd n, trt(t) stud(id) nmiss(m)

(click to run)

- Run the ACA:

. metamiss2

(click to run)

- Explore the impact of alternative assumptions by incorporating IMPs in the analysis. Consider three groups of treatments with IMDOM=1,-1 or 0 but sd(IMDOM)=1
for all treatments in the network. Also, allow the correlation of IMPs to differ across studies by specifying the full 9x9 correlation matrix:

mat C=J(9,9,0.5)+0.5*I(9)

forvalues i=4/8{

mat C[`i',`=`i'+1']=0.2

mat C[`=`i'+1',`i']=0.2

}

mat li C

(click to run)

. metamiss2, impmean(1 1 -1 -1 0 1 0 1 -1) impsd(1) impcorr(C) b

(click to run)

Authors

Anna Chaimani, Paris Descartes University, Paris, France

anna.chaimani@parisdescartes.fr

Ian R. White, MRC Clinical Trials Unit at UCL, London, UK

ian.white@ucl.ac.uk

Acknowledgements

Drs Dimitris Mavridis and Georgia Salanti provided very helpful comments on earlier versions of the command.

References

Chaimani A, Mavridis D, Higgins JPT, Salanti G, White IR. Allowing for informative missingness in
aggregate data meta-analysis with continuous or binary outcomes: Extensions to metamiss. The Stata Journal 2018; 18(3):716-740.
(link to paper)

Cipriani A, Furukawa TA, Salanti G, Geddes JR, Higgins J, Churchill R et al. Comparative efficacy and acceptability of
12 new-generation antidepressants : a multiple-treatments meta-analysis. Lancet 2009; 373:746-758.
(link to paper)

Higgins JPT, White IR, Wood AM.
Imputation methods for missing outcome data in meta-analysis of clinical trials.
Clin Trials 2008, 5: 225-239.
(link to paper)

Joy CB, Adams CE, Lawrie SM. Haloperidol versus placebo for schizophrenia.
Cochrane Database Syst Rev 2006; 4: CD003082.
(link to paper)

Mavridis D, White IR, Higgins JPT, Cipriani A, Salanti G.
Allowing for uncertainty due to missing continuous outcome data in pairwise and network meta-analysis.
Stat Med 2015, 34: 721-741.
(link to paper)

White IR, Higgins JPT, Wood AM. Allowing for uncertainty due to missing data in meta-analysis-Part 1: two-stage methods. Stat Med 2008, 27: 711-727.
(link to paper)

White IR, Welton NJ, Wood AM, Ades AE, Higgins JPT. Allowing for uncertainty due to missing data in meta-analysis-Part 2: hierarchical models. Stat Med 2008, 27: 728-745.
(link to paper)

See also

metan, metamiss, network, network graphs.